VBA Control of Adobe Acrobat Professional

Adobe Acrobat Professional is more automatically controlled by JavaScript, another computer language, but Adobe has provided Inter-Application Communication (IAC) that allows VBA to interface with JavaScript.

From any primary VBA application such as Microsoft Word or CorelDraw you can control Acrobat Professional to;

combine multiple Acrobat files into one,
delete pages from an Acrobat file,
count the number of pages in an Acrobat file,
insert a page into an Acrobat file,
move pages including reversing the page order,
search an Acrobat file for text,
copy text,
crop pages,
rotate pages,
save or save to another pdf,
work with bookmarks although it is it bit limited.

All the code on this page can be run from any application that fully supports VBA, such as Microsoft Word, PowerPoint, Excel, CorelDraw etc.

When controlling Acrobat reference Adobe Acrobat __ Type Library. ie acrobat.tlb
The __ undersores represent the version of acrobat. ie 9.0 or 10 etc.
With the Adobe Acrobat Type Library you can define 3 important objects.
acroApp is the acrobat object whilst acroAVDoc and acroPDDoc are the acrobat's methods and properties.

In books and on the internet you can find definitions with an additional C in front of definitions such as CAcroApp, CAcroAVDoc, CAcroPDDoc, CAcroPDTextSelect, CAcroHiliteList etc.
The leading C can be dispensed with for VBA. It has no effect.

acroApp
    Dim <Your Variable Name> As Acrobat.acroApp
    Set <Your Variable Name> = CreateObject("AcroExch.App")

acroAVDoc
    Dim <Your Variable Name> As Acrobat.acroAVDoc
    Set <Your Variable Name> = CreateObject("AcroExch.AVDoc")

acroPDDoc
    Dim <Your Variable Name> As Acrobat.acroPDDoc
    Set <Your Variable Name> = CreateObject("AcroExch.PDDoc")

Opening Acrobat
There are 2 ways to open Acrobat.
Visibly as an AVDoc or hidden as PDDoc.
Every AVDoc has a PDDoc behind the scenes, and that object can be retrieved via the AVDoc.GetPDDoc method.
A PDDoc only has an associated AVDoc if it is actually shown in Acrobat.
You cannot retrieve the AVDoc object from within the PDDoc.


Open a PDF Visibly
'AVDoc's are visible versions of Acrobat.
'Every AVDoc has a PDDoc behind the scenes, and that object can be retrieved via the AVDoc.GetPDDoc method.

    Dim acroApp As Acrobat.acroApp
    Dim avDoc As Acrobat.acroAVDoc
        
    Set acroApp = CreateObject("AcroExch.App")
    Set avDoc = CreateObject("AcroExch.AVDoc")
        
    'avDoc.Open FileLocation, TitleToDisplay
    avDoc.Open "D:\Users\User\Desktop\Test.pdf", "PDF Title"
    avApp.Show
        
    'The next 2 lines to refer to the PDDoc from an AVDoc
    Dim pdDoc As Acrobat.AcroPDDoc
    Set pdDoc = acroDoc.GetPDDoc
        
    Set pdDoc = Nothing
    Set avDoc = Nothing
    Set acroApp = Nothing
    

Hidden PDF
PDDoc are hidden Acrobat documents.
AVDoc are visible Acrobat documents.
You cannot retrieve the AVDoc object from within the PDDoc but a PDDoc will allow you to open its associated AVDoc.

    Dim pdDoc As Acrobat.AcroPDDoc 'or .CAcroPDDoc
        
    Set pdDoc = CreateObject("AcroExch.PDDoc")

    pdDoc.Open "D:\Users\User\Desktop\Test.pdf"
    'The acrobat is now open but invisible.
        
    'Create an AVDoc from a PDDoc if you wish to make the pdf visible.
    'OpenAVDoc and give the pdf a title that is not necessarily the name of the file.
    pdDoc.OpenAVDoc "Title"
        
    'When you manually close a visible acrobat the acrobat application will close.
    'However if you did not make acrobat visible then you can not easily close acrobat.
    'You should use the following code to close the hidden acrobat application.
    'pdDoc.Close
        
    Set pdDoc = Nothing
    Set acroApp = Nothing
      

Closing Acrobat
Sometimes for what ever reason Acrobat will not close with acroApp.Exit
To force a closure you can use the following API code.
The code is written for a 64 bit system.
The 2 Declare statements and Const must be before any Subs or Functions, and they must not be within a sub or Function.

      Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
      Declare PtrSafe Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As LongPtr, ByVal wMsg As Long, ByVal wParam As LongPtr, lParam As Any) As LongPtr
      Public Const WM_CLOSE = &H10
          
      Sub CloseAcrobat()
          Dim hwnd As LongPtr
          hwnd = FindWindow("AcrobatSDIWindow", vbNullString)
          'Close down Notepad.
          SendMessage hwnd, WM_CLOSE, 0&, 0&
      End Sub

Determine the Number of Pages in an Open PDF

    Dim acroApp As acroApp
    Dim avDocAs AcroAVDoc
    Dim pdDoc As AcroPDDoc
    Dim intNoPages As Integer
          
    'Create an Acrobat object.
    Set acroApp = CreateObject("AcroExch.App")
      
    'Get the already opened PDF file.
    Set avDoc = acroApp.GetActiveDoc
      
    'Get the pdDoc of the avDoc.
    Set pdDoc = avDoc.GetPDDoc
      
    intNoPages = pdDoc.GetNumPages
      
    Set pdDoc = Nothing
    Set avDoc = Nothing
    Dim acroApp As Nothing
  

Move Pages in a PDF
Acrobat numbers pages from zero. The first page is zero.

MovePage(x, y) moves single pages.
MovePage(New page No, Old page No)
If x = y then no pages move.

To move a page to the front.
MovePage(0, Old page No)

To move page 4 to page 8.
MovePage(7,3)


To Move Pages In An Already Opened PDF

    Dim acroApp As acroApp
    Dim avDoc As AcroAVDoc
    Dim pdDoc As AcroPDDoc
    Dim bnSuccess As Boolean
        
    'Create an Acrobat object.
    Set acroApp = CreateObject("AcroExch.App")
        
    'Get the already opened PDF file.
    Set avDoc = acroApp.GetActiveDoc
        
    Set pdDoc = avDoc.GetPDDoc
        
    'ie Move to page 4, page 2.
    bnSuccess = pdDoc.MovePage(3, 1)
    'or
    'pdDoc.MovePage 3, 1
        
    Set pdDoc = Nothing
    Set avDoc = Nothing
    Set acroApp = Nothing
    

Moving Through the Pages of a PDF File.
There does not appear to be a defined variable for a collection of Pages.
So you cannot use For each Page in pdDoc.Pages
Instead you must step through the pdf file via each page number.
Remember page 0 is the first page.

    Dim pdDoc As AcroPDDoc
    Dim acroPage As AcroPDPage
    Dim intPageCounter As Integer
        
    Set pdDoc = CreateObject("AcroExch.PDDoc")
        
    'The path is case sensitive.
    pdDoc.Open ("D:\Users\User\Desktop\Test.pdf")
        
    'Get each page.
    For intPageCounter = 0 To pdDoc.GetNumPages - 1
        Set acroPage = pdDoc.AcquirePage(lngPageCounter)
        'Some code goes here.
        Set acroPage = Nothing
    Next intPageCounter
    pdDoc.Close
        
    Set pdDoc = Nothing
    

Rotate a Page
A page in a pdf that has been rotated remembers its degree of rotation.
This previous rotation angle can be determined by using GetRotate.
To return the rotation back to the original angle when the pdf was created you use SetRotate 0.

If a page has already been been rotated to get it to rotate a further 90 degrees use
    acroPage.SetRotate acroPage.GetRotate + 90

    Dim acroApp As Acrobat.acroApp
    Dim pdDoc As Acrobat.AcroPDDoc
    Dim acroPage As AcroPDPage
        
    Set acroApp = New acroApp
    acroApp.Show
    '.Maximize
    'If the argument is a positive number, the Acrobat application is maximized.
    'If the argument is 0 the Acrobat application is returned to its normal state.
    acroApp.Maximize 1
        
    Set pdDoc = New AcroPDDoc
    pdDoc.Open "D:\Users\Graeme\Desktop\Test.pdf"
    pdDoc.OpenAVDoc "Working Doc"
        
    'Set page object
    Set acroPage = pdDoc.AcquirePage(0)
    acroPage.SetRotate 90
        
    'Other Methods & Properties are;
    'acroPage.AddAnnot
    'acroPage.AddNewAnnot
    'acroPage.CopyToClipboard
    'acroPage.CreatePageHilite
    'acroPage.CreateWordHilite
    'acroPage.CropPage
    'acroPage.Draw
    'acroPage.DrawEx
    'acroPage.GetAnnot
    'acroPage.GetAnnotIndex
    'acroPage.GetDoc
    'acroPage.GetNumAnnots
    'acroPage.GetNumber
    'acroPage.GetRotate(Degrees clockwise)
    'acroPage.GetSize
    'acroPage.RemoveAnnot
    'acroPage.SetRotate
        
    Set acroPage = Nothing
    Set pdDoc = Nothing
    Set acroApp = Nothing
    

Reverse the Page Order of a PDF

    Dim acroApp As acroApp
    Dim pdDoc As AcroPDDoc
    Dim intNoPages As Integer
    Dim intInsertPageNo As Integer
        
    Set acroApp = CreateObject("AcroExch.App")
        
    Set pdDoc = CreateObject("AcroExch.PDDoc")
        
    'pdDoc.Open (Case sensitive full path to pdf)
    pdDoc.Open ("C:\Users\User\Desktop\Test.pdf")
        
    'Determine the total number of pages in the original document.
    intNoPages = pdDoc.GetNumPages()
        
    '***************************************************************
    'Important: Acrobat numbers pages from zero being the first page.
    'This makes it confusing.
    '***************************************************************
        
    'Copy a page from the back of pdDoc towards the front of pdDoc.
    'intInsertPageNo does not just move pages but copies them as well.
    'InsertPages(nInsertPageAfter As Long, iPDDocSource As Object, lngStartPage As Long, lnNoPages As Long, lngInsertBookmarks As Long) As Boolean
    'If nInsertPageAfter = -1 then place copy before 1st page.
    'If nInsertPageAfter = 0 then place copy after 1st page.
    'If nInsertPageAfter = 1 then place copy after 2nd page.
    'lngInsertBookmarks = 0 ie False do not merge Bookmarks.
        
    For intInsertPageNo = 1 To intNoPages
        pdDoc.InsertPages intInsertPageNo - 2, pdDoc, intNoPages - 1, 1, 0
    Next intInsertPageNo
        
    'Delete the original pages.
    'DeletePages(nStartPage As Long, nEndPage As Long)
    'For some reason acrobat remembers the page numbers of the original sheets, not their new position.
    pdDoc.DeletePages intNoPages, intNoPages * 2 - 1
        
    'Save the pdf.
    'Insert your path and file name here for the new pdf.
    If pdDoc.Save(PDSaveFull, "C:\Users\User\Desktop\Reversed.pdf") = False Then
        MsgBox "Cannot save the modified pdf."
    End If
        
    pdDoc.Close
    acroApp.Exit
    Set pdDoc = Nothing
    Set acroApp = Nothing
    

Shuffle Pages
Switch the page positions so that the even and odd pages swap positions.

    Dim acroApp As acroApp
    Dim pdDoc As AcroPDDoc
    Dim intNoPages As Integer
    Dim intInsertPageNo As Integer
        
    Set acroApp = CreateObject("AcroExch.App")
    Set pdDoc = CreateObject("AcroExch.PDDoc")
        
    'The pages in pdDoc will be placed in reverse order.
    pdDoc.Open ("C:\Users\User\Desktop\Test.pdf")
    'Determine the total number of pages in the original document.
    intNoPages = pdDoc.GetNumPages()
        
    intInsertPageNo = 0
        
    '***************************************************************
    'Important: Acrobat numbers pages from zero being the first page.
    'This makes it confusing.
    '***************************************************************
        
    'InsertPages(nInsertPageAfter As Long, iPDDocSource As Object, _
    'lngStartPage As Long, lnNoPages As Long, lngInsertBookmarks As Long) As Boolean
    'lngInsertBookmarks = 0 ie False do not merge Bookmarks.
    'Insert the 1st page to the 2nd page. ie Move every 2nd page back.
    For intInsertPageNo = 0 To intNoPages Step 2
        pdDoc.InsertPages intInsertPageNo + 1, pdDoc, intInsertPageNo, 1, 0
        'InsertPages moves a copy of a page but does not delete the original page so it must be deleted.
        'DeletePages(nStartPage As Long, nEndPage As Long)
        pdDoc.DeletePages intInsertPageNo, intInsertPageNo
    Next intInsertPageNo
        
    'Save the pdf. If you want you can save the pdf to another name so as not to alter the original file.
    If pdDoc.Save(PDSaveFull, "C:\Users\User\Desktop\Test.pdf") = False Then
        MsgBox "Cannot save the modified document"
    End If
        
    pdDoc.Close
    acroApp.Exit
    Set pdDoc = Nothing
    Set acroApp = Nothing